@verb #12:"_rename_obj" this none this rxdo #55
@program #12:"_rename_obj" this none this
"Rename an object.  Called by @rename."
set_task_perms(caller_perms())
{object, iobjstr} = args
iobjstr = player:input_get_raw(iobjstr)
old_name = object.name
old_aliases = object.aliases
new_names = $building_utils:parse_names(iobjstr)
new_name = new_names[1] || object.name
if (object:isa($player))
  name_database = $player_db
elseif (object:isa($room))
  name_database = $room_db
else
  name_database = $nothing
endif
try
  r = object:_set_aliases(new_names[2]) && object:_set_name(new_name)
  if (!r)
    return player:tell(r)
  endif
  new_aliases = setremove(object.aliases, object.name)
  $msg:mtell(new_aliases ? "renamed_aka" | "renamed", object, new_aliases)
except (E_INVARG)
  for name in (new_names)
    if (m = name_database:why_not_available(name))
      return player:tell("You cannot use the name ", name, " because ", m)
    endif
  endfor
  return $msg:mtell("rename_bad")
except (E_NACC)
  return $msg:mtell("db_frozen")
except (E_ARGS)
  return $msg:mtell("rename2long")
except e (ANY)
  return player:tell(e)
endtry
"Last modified by Cecil (#7407) on Fri Aug 23 12:35:11 2002 MDT."
.