@verb #12:"_confunc" this none this rxdo #55
@program #12:"_confunc" this none this
$perm_utils:is_called_from($login, "user_connected") || raise(E_PERM)
if (this:first_connection())
  this:tell($msg:msg_first_connect())
  while (typeof(resp = `$cmd_utils:yes_or_no("Do you understand and promise to abide by these policies?") ! E_INVARG') == $ERR)
  endwhile
  if (!resp)
    player:tell("Sorry you don't wish to join us.  Good bye!")
    boot_player(this)
  endif
  this:tell("*** Connected ***")
elseif (!this:isa($guest))
  if (this.last_disconnect_time != 0)
    player:tell("You were last here on ", player:ctime(this.last_disconnect_time), ".")
  endif
endif
"nm = this:length_all_msgs() - this:length_date_le(this:get_current_message()[2]);"
nm = length(this:unread_messages(this))
if (nm)
  this:tell("<font color=#FFFF00>You have new mail (", nm, " message", nm == 1 ? "" | "s", ").", this:mail_option("expert") ? "</FONT>" | "  Type '<A xch_cmd=\"@mail\">@mail</A>' for info on reading it.</FONT>")
endif
this:mail_catch_up()
this:check_mail_lists()
this:clean_quota_contribs()
$scheduler:run(15.0, $postman, "mail_for_me", {}, this, this)
this.gaglist = setremove(this.gaglist, #-1)
this.notified_of_pending_repo = 0
if (this:isa($guest))
  $wiz_utils:mentor_alert(this.name, " connects.")
elseif (parent(this) == $player)
  $wiz_utils:mentor_alert(this.name, " (a $player) has connected.")
endif
"Last modified by Dax (#789) on Tue May  3 13:45:55 2005 MDT."
.