@verb #12:"@unsub*scribe" any any any rdo #55
@program #12:"@unsub*scribe" any any any
"@unsubscribe [*<folder/mailing_list> ...]"
"entirely removes the record of your current message for the named folders,"
"indicating your disinterest in anything that might appear there in the future."
set_task_perms(player)
unsubscribed = {}
current_folder = this:current_folder()
for a in (args || {0})
  if (a ? $mail_agent:match_failed(folder = $mail_agent:match_recipient(a), a) | (folder = current_folder))
    "...bogus folder name, done...  No, try anyway."
    if (this:kill_current_message(this:my_match_object(a)))
      player:notify("Invalid folder, but found it subscribed anyway.  Removed.")
    endif
  elseif (folder == this)
    player:notify(tostr("You can't ", verb, " yourself."))
  else
    for msg in (`folder.messages ! E_PERM => {}')
      try
        $mail_db:set_message_read(msg[3], player, folder)
      except (E_RANGE)
      endtry
      $cmd_utils:suspend_if_needed(0)
    endfor
    if (!this:kill_current_message(folder))
      player:notify(tostr("You weren't subscribed to ", $mail_agent:name(folder)))
      if ($object_utils:isa(folder, $newsgroup))
        result = folder:delete_notify(this)
        if (typeof(result) == $LIST && result[1] == this)
          player:notify("Removed you from the mail notifications list.")
        endif
      endif
    else
      unsubscribed = {@unsubscribed, folder}
      if ($object_utils:isa(folder, $newsgroup))
        folder:delete_notify(this)
      endif
    endif
  endif
endfor
if (unsubscribed)
  player:notify(tostr("Unsubscribing ", $string_utils:english_list($list_utils:map_arg($mail_agent, "name", unsubscribed))))
  if (current_folder in unsubscribed)
    this:set_current_folder(this)
  endif
endif
"Last modified by Dax (#789) on Tue May  3 13:55:52 2005 MDT."
.