@verb #12:"@unrmm*ail" any any any rdo #55
@program #12:"@unrmm*ail" any any any
"@unrmm [on <recipient>]  -- undoes the previous @rmm on that recipient."
set_task_perms(player)
if (!(p = this:parse_folder_spec("@unrmm", args, "on")))
  return
endif
dobjstr = $string_utils:from_list(p[2], " ")
if (!dobjstr)
  do = "undo_rmm"
elseif (index("expunge", dobjstr) == 1)
  do = "expunge_rmm"
elseif (index("list", dobjstr) == 1)
  do = "list_rmm"
else
  player:notify(tostr("Usage:  ", verb, " [expunge|list] [on &lt;recipient&gt;]"))
  return
endif
this:set_current_folder(folder = p[1])
if (msg_seq = folder:(do)())
  if (do == "undo_rmm")
    player:notify(tostr($seq_utils:size(msg_seq), " messages restored to ", $mail_agent:name(folder), "."))
    folder:display_seq_headers(msg_seq, 0)
  else
    player:notify(tostr(msg_seq, " zombie message", msg_seq == 1 ? " " | "s ", do == "expunge_rmm" ? "expunged from " | "on ", $mail_agent:name(folder), "."))
  endif
elseif (typeof(msg_seq) == $ERR)
  player:notify(tostr(msg_seq))
else
  player:notify(tostr("No messages to ", do == "expunge_rmm" ? "expunge from " | "restore to ", $mail_agent:name(folder)))
endif
"Last modified by Dax (#789) on Tue May  3 13:45:55 2005 MDT."
.