@verb #12:"@ungag" any none none rxdo #55
@program #12:"@ungag" any none none
if (player != this || (caller != this && !$perm_utils:controls(caller_perms(), this)))
  player:tell(E_PERM)
elseif (dobjstr == "")
  player:tell("Usage:  ", verb, " <player>  or  ", verb, " all")
elseif (dobjstr in {"everyone", "everything", "all"})
  this.gaglist = {}
  player:notify("You are no longer gagging anyone or anything.")
else
  if (valid(dobj))
    match = dobj
  elseif ((match = toobj(dobjstr)) > #0)
  else
    match = $string_utils:match(dobjstr, this.gaglist, "name", this.gaglist, "aliases")
  endif
  if (match == $failed_match)
    player:notify(tostr("You don't seem to be gagging anything named ", dobjstr, "."))
  elseif (match == $ambiguous_match)
    player:notify(tostr("I don't know which \"", dobjstr, "\" you mean."))
  else
    this.gaglist = setremove(this.gaglist, match)
    player:notify(tostr(valid(match) ? match.name | match, " removed from gag list."))
  endif
  this:("@listgag")("but don't fork")
endif
"Last modified by Dax (#789) on Sun May 17 17:32:46 1998 EDT."
.