@verb #12:"@subscribe @unsubscribed" any any any rdo #55
@program #12:"@subscribe @unsubscribed" any any any
"@subscribe *<folder/mailing_list> [with notify]"
"  causes you to be notified of new mail on this list (either when you connect, or when new mail arrives)"
"@subscribe"
"   just lists available mailing lists."
set_task_perms(player)
if (!dobjstr)
  ml = $list_utils:slice(player.current_message[3..$])
  ngs = $list_utils:remove_duplicates({@$mail_agent.contents, @this.mail_lists})
  ngs = $newsgroups:sort_groups(ngs)
  for c in (ngs)
    $command_utils:suspend_if_needed()
    if (c:is_usable_by(player) || c:is_readable_by(player) && (verb != "@unsubscribed" || !(c in ml)))
      `c:look_self() ! ANY => "prevents nasty mailers from borking the rest"'
    endif
  endfor
  player:notify(tostr("-------- end of ", verb, " -------"))
  return
elseif ($mail_agent:match_failed(folder = $mail_agent:match_recipient(dobjstr), dobjstr))
  return
elseif (folder == this)
  player:notify("You don't need to @subscribe to yourself")
  return
elseif (!$perm_utils:controls(this, folder) && folder:isa($newsgroup) ? !folder:is_readable_by(this) | 0)
  player:notify("That mailing list is not readable by you.")
  if (!$command_utils:y_or_n("Subscribe anyways?  (mail will not be readable by you)"))
    return
  endif
endif
this:make_current_message(folder)
notification = iobjstr && iobjstr[1] == "n"
if ($object_utils:isa(folder, $newsgroup) && notification)
  folder:add_notify(this)
endif
make_believe_seq = folder:parse_message_seq("1..$")
if (typeof(make_believe_seq) == $LIST)
  for msg in [make_believe_seq[1][1]..make_believe_seq[1][$]]
    if (msg_id = `folder:get_message_id(msg) ! ANY')
      $mail_db:set_message_unread(msg_id, player, folder)
    endif
    $cmd_utils:suspend_if_needed(0)
  endfor
endif
len = folder:length_all_msgs()
player:tell(tostr($mail_agent:name(folder), " has ", len, " message", len == 1 ? "" | "s", ".", notification ? "  You will be notified immediately when new messages are posted." | "  Notification of new messages will be printed when you connect."))
this:set_current_folder(folder)
"Last modified by Dax (#789) on Tue May  3 13:45:01 2005 MDT."
.