@verb #12:"@skip" any any any rdo #55
@program #12:"@skip" any any any
"Copied from Plarf (#9682):@skip Aug 13 16:16:42 2002"
"@skip [number of messages to skip [on]] [*<folder/mailing_list>...]"
"  marks the appropriate number of messages as read, or if no"
"  number is given, all messages."
current_folder = this:current_folder()
total = $maxint
if (argstr && dobjstr && toint(dobjstr) != 0 && !index(dobjstr, "#"))
  total = toint(dobjstr)
  args[0..1] = {}
  args[1] == "on" && (args[0..1] = {})
endif
if (argstr == "all")
  args = $list_utils:slice(this.current_message[3..$], 1)
  for x in (args)
    args[x in args] = tostr(x)
  endfor
endif
for a in (args || {0})
  if (a ? $mail_agent:match_failed(folder = $mail_agent:match_recipient(a), a) | (folder = this:current_folder()))
    "...bogus folder name, done...  No, try anyway."
    if (this:kill_current_message(this:my_match_object(a)))
      player:notify("Invalid folder, but found it subscribed anyway.  Removed.")
    endif
  else
    if (folder:isa($player) ? !$perm_utils:controls(this, folder) | !folder:is_readable_by(player))
      player:tell("Hey, you can't read " + folder:title() + "!  Nice try...")
      continue
    endif
    count = 0
    for msg in (folder:unread_messages(player))
      if (msgid = `folder:get_message_id(msg) ! ANY')
        $mail_Db:set_message_read(msgid, player, folder)
        count = count + 1
        if (count >= total)
          break
        endif
      endif
      $cmd_utils:suspend_if_needed(0)
    endfor
    player:tell(tostr(count ? tostr("Ignoring ", count) | "No", " unread message", count != 1 ? "s" | "", " on ", $mail_agent:name(folder)))
    if (current_folder == folder)
      this:set_current_folder(this)
    endif
  endif
endfor
"Last modified by Dax (#789) on Tue May  3 14:09:29 2005 MDT."
.