@verb #12:"@set-note-string @set-note-text @set-note-value" any none none rdo #55
@program #12:"@set-note-string @set-note-text @set-note-value" any none none
"Usage:  @set-note-{string | text} {#xx | #xx.pname}"
"        ...lines of text..."
"        ."
""
"For use by clients' local editors, to save new text for a note or object property.  See $note_editor:local_editing_info() for details."
set_task_perms(player)
text = $command_utils:read_lines(1)
if (verb == "@set-note-string" && length(text) <= 1)
  text = text ? text[1] | ""
endif
isfile = !!index(argstr, "!")
if (spec = $code_utils:("parse_" + (isfile ? "file" | "prop") + "ref")(argstr))
  o = toobj(spec[1])
  p = spec[2]
  if (isfile)
    try
      e = o:filewrite(p, text)
      if (o:fileread(p) != text)
        player:tell("Error: ", e)
      else
        player:tell("Set ", p, " file of ", o:nn(), ".")
      endif
    except r (ANY)
      player:tell("Error: ", r)
    endtry
  else
    if (verb == "@set-note-value")
      text = $su:to_value(text[1])
      if (text[1])
        text = text[2]
      else
        return player:tell("Error: ", text[2])
      endif
    endif
    e = o:("_set_" + p)(text)
    if (e != text)
      player:tell("Error: ", e)
    else
      player:tell("Set ", p, " property of ", o.name, " (", o, ").")
    endif
  endif
elseif (typeof(note = $code_utils:toobj(argstr)) == $OBJ)
  try
    note:set_text(text)
  except e (ANY)
    return player:tell("Error: ", e)
  endtry
  player:tell("Set text of ", note.name, " (", note, ").")
else
  player:tell("Error: Malformed argument to ", verb, ": ", argstr)
endif
"Last modified by Dax (#789) on Tue May  3 13:47:06 2005 MDT."
.