@verb #12:"@ren*ame 2rename @copy*! 2copy*! @move*! 2move*!" any at/to any rdo #55
@program #12:"@ren*ame 2rename @copy*! 2copy*! @move*! 2move*!" any at/to any
"Bounce the @rename, @copy or @move request to the verb specializing in performing that operation on objects, properties, files or verbs."
verb = {"rename", "copy", "move"}[verb[2..4] in {"ren", "cop", "mov"}] + (verb[$] == "!" ? "!" | "")
set_task_perms(player)
if (player != this)
  $msg:mtell("huh")
elseif (!iobjstr)
  player:tell(verb, " ", dobjstr, " ", prepstr, " what?")
elseif (valid(dobj))
  "'@move $foo to here' does not mean '@move #0.foo to here'"
  if (valid(iobj) && verb != "rename")
    "And '@copy me:bar to $foo' does not mean '@move me:bar to #0.foo' either"
    iobjstr = tostr(iobj)
  endif
  this:("_" + verb + "_obj")(dobj, iobjstr)
elseif (spec = $code_utils:parse_fileref(dobjstr))
  object = this:my_match_object(spec[1])
  if (!$command_utils:object_match_failed(object, spec[1]))
    this:("_" + verb + "_file")(object, spec[2], iobjstr)
  endif
elseif (spec = $code_utils:parse_propref(dobjstr))
  object = this:my_match_object(spec[1])
  if (!$command_utils:object_match_failed(object, spec[1]))
    this:("_" + verb + "_prop")(object, spec[2], iobjstr)
  endif
elseif (spec = $code_utils:parse_verbref(dobjstr))
  object = this:my_match_object(spec[1])
  if (!$command_utils:object_match_failed(object, spec[1]))
    this:("_" + verb + "_verb")(object, spec[2], iobjstr)
  endif
else
  object = this:my_match_object(dobjstr)
  if (!$command_utils:object_match_failed(object, dobjstr))
    this:("_" + verb + "_obj")(object, iobjstr)
  endif
endif
"Last modified by MadHatter (#8371) on Fri Aug  9 02:18:18 2002 MDT."
.