@verb #12:"@quota @@quota" any none none rxdo #3887
@program #12:"@quota @@quota" any none none
"Written by Daryl (#3887) Jun 26 00:17:47 1998"
if (caller != this)
  return $msg:mtell("huh")
elseif (dobjstr == "")
  dobj = this
elseif ($command_utils:player_match_failed(dobj = this:match_entity(dobjstr), dobjstr))
  return
endif
"Initializes a few necessary variables."
total = {dobj:_get_max_obj(), dobj:_get_max_vm() / $kb, dobj:_get_max_fs() / $kb}
free = {dobj:free_objects(), dobj:free_bytes() / $kb, dobj:free_dbytes() / $kb}
type = {"Object: ", "Byte:   ", "Disk:   "}
unit = {"  (objects)", "(kilobytes)", "(kilobytes)"}
"Prints the formated quota statistics"
player:tell("@quota info for ", $su:nn(dobj))
for i in [1..length(total)]
  player:tell(free[i] < 0 ? " *" | "  ", type[i], " ", $su:left(tostr(total[i] - free[i], " of ", total[i]), 15), unit[i])
endfor
"Displays the contributions."
if (verb[2] != "@" && dobj.quota_contribs)
  type = {"Byte", "Object", "Disk"}
  actions = {"Contributed", "Received"}
  headers = {"Who", "What", "Type", "Amount"}
  data = {}
  for i in (dobj.quota_contribs)
    for n in [2..4]
      data = i[n] != 0 ? {@data, {$su:nn(i[1]), actions[(i[n] < 0) + 1], type[n - 1], n in {2, 4} ? $quota:kb_string(abs(i[n])) | abs(i[n])}} | data
    endfor
  endfor
  player:tell("")
  if (data)
    player:tellColumns({1, 1, 1, 1}, headers, @data)
  endif
endif
"Last modified by Dax (#789) on Thu Apr 15 09:13:12 1999 MDT."
.