@verb #12:"@old-quota" any none none rxdo #55
@program #12:"@old-quota" any none none
"Prints out the quota stats for the requested player."
"Also gives or revokes the .programmer bit to repentant/delinquent players"
if (caller != this)
  return
elseif (dobjstr == "")
  dobj = this
elseif ($command_utils:player_match_failed(dobj = this:match_entity(dobjstr), dobjstr))
  return
endif
spaceleft = dobj:free_bytes()
spacetotal = dobj:_get_max_vm(dobj) / $kb
if (spaceleft < 0 && dobj:is_over_quota())
  this:sub_tell("%D uses %1 too many kilobytes. %D~S will not be able to create any more objects NOR VERBS until this deficit is cleared.", -spaceleft / $kb)
else
  this:sub_tell("%D has a byte-quota of %2k, of which %1k are free.", spaceleft / $kb, spacetotal)
endif
qo = dobj:_get_max_obj()
lo = qo - dobj:free_objects()
if (lo < qo)
  this:sub_tell("%D has created %1 objects out of a possible %2.", lo, qo)
elseif (lo == qo)
  this:sub_tell("%D has created the maximum possible %1 objects.", lo)
else
  this:sub_tell("%D has created %1 objects, of which %d~s should only have been able to create %2.", lo, qo)
endif
if (dobj:free_objects() <= 0)
  this:sub_tell("%D~S won't be able to create any new objects until old ones are recycled.")
endif
dquota = dobj:_get_max_fs()
dfree = dobj:free_dbytes()
dsize = dquota - dfree
if (dfree <= 0)
  this:sub_tell("%D uses %1 too many kilobytes of disk space. %D~S will not be able to use any more disk space until this deficit is cleared.", -dfree / $kb)
else
  this:sub_tell("%D has a disk-quota of %2k, of which %1k are free.", dfree / $kb, dquota / $kb)
endif
for x in (dobj.quota_contribs)
  parts = {}
  if (x[2..4] == {0, 0, 0})
  else
    if (x[2])
      parts = {@parts, $msg:substitute(this, "%1 %2 of byte quota", x[2] > 0 ? "contributed" | "received", $quota:kb_string((x[2] < 0 ? -1 | 1) * x[2]))}
    endif
    if (x[3])
      parts = {@parts, $msg:substitute(this, "%1 %2 objects", x[3] > 0 ? "contributed" | "received", (x[3] < 0 ? -1 | 1) * x[3])}
    endif
    if (x[4])
      parts = {@parts, $msg:substitute(this, "%1 %2 of disk quota", x[4] > 0 ? "contributed" | "received", $quota:kb_string((x[4] < 0 ? -1 | 1) * x[4]))}
    endif
    this:sub_tell("%d has %1 %2 %3.", parts, index(parts[$], "contrib") ? "to" | "from", x[1])
  endif
endfor
"Last modified by Dax (#789) on Thu Nov  8 15:28:55 2001 MST."
.