@verb #12:"@mailo*ptions @mail-o*ptions @edito*ptions @edit-o*ptions @displayo*ptions @display-o*ptions @visual-o*ptions @visualo*ptions @general-o*ptions @generalo*ptions @build-o*ptions @buildo*ptions @builder-o*ptions @buildero*ptions" any any any rdo #55
@program #12:"@mailo*ptions @mail-o*ptions @edito*ptions @edit-o*ptions @displayo*ptions @display-o*ptions @visual-o*ptions @visualo*ptions @general-o*ptions @generalo*ptions @build-o*ptions @buildo*ptions @builder-o*ptions @buildero*ptions" any any any
"@<what>-option <option> [is] <value>   sets <option> to <value>"
"@<what>-option <option>=<value>        sets <option> to <value>"
"@<what>-option +<option>     sets <option>   (usually equiv. to <option>=1"
"@<what>-option -<option>     resets <option> (equiv. to <option>=0)"
"@<what>-option !<option>     resets <option> (equiv. to <option>=0)"
"@<what>-option <option>      displays value of <option>"
set_task_perms(player)
what = {"mail", "edit", "display", "visual", "general", "builder"}[index("medvgb", verb[2])]
options = what + "_options"
option_pkg = #0.(options)
set_option = "set_" + what + "_option"
if (!args)
  player:notify({"Current " + what + " options:", "", @option_pkg:show(this.(options), option_pkg.names)})
  return
elseif (typeof(presult = option_pkg:parse(args)) == $STR)
  player:notify(presult)
  return
else
  if (length(presult) > 1)
    if (typeof(sresult = this:(set_option)(@presult)) == $STR)
      player:notify(sresult)
      return
    elseif (!sresult)
      player:notify("No change.")
      return
    endif
  endif
  player:notify(option_pkg:show(this.(options), presult[1]))
endif
"Last modified by Dax (#789) on Tue May  3 13:43:06 2005 MDT."
.