@verb #12:"@iplist @uniplist" any none none rdo #789
@program #12:"@iplist @uniplist" any none none
if (player != this)
  return $msg:mtell("huh")
endif
if (dobjstr)
  if (verb == "@iplist")
    if (dobjstr in this.IPlist)
      player:tell("'", dobjstr, "' is already in your IP list.")
    else
      if (!$cmd_utils:yes_or_no("Add '" + dobjstr + "' to your iplist? (This restricts what internet addresses you can connect from!)"))
        return
      endif
      player:tell("'", dobjstr, "' has been added to your IP list.")
      this.IPlist = setadd(this.IPlist, dobjstr)
    endif
  else
    if (dobjstr in this.IPlist)
      this.IPlist = setremove(this.IPlist, dobjstr)
      player:tell("'", dobjstr, "' has been removed from your IP list.")
    else
      player:tell("'", dobjstr, "' was not in your IP list.")
    endif
  endif
endif
if (this.IPlist)
  player:tell({"You may only login from these sites:", @this.IPlist})
  host = $string_utils:connection_hostname(connection_name(player))
  player:tell("This IP list ", $login:IPlisted(host, player) ? "DOES" | "DOES NOT", " allow you to login from your current connection site (", host, ").")
else
  player:tell("Your IP list is empty.  You may login from anywhere.")
endif
"Last modified by Dax (#789) on Mon Dec 10 21:08:32 2001 MST."
.