@verb #12:"@give*quota" any at/to any rdo #55
@program #12:"@give*quota" any at/to any
if (player != this)
  return player:tell(E_PERM)
elseif ($command_utils:player_match_failed(victim = player:match_entity(iobjstr), iobjstr))
  return
endif
if (dobjstr)
  try
    amount = $quota:parse_amount(dobjstr)
  except error (E_INVARG)
    return player:tell("Invalid quota quantity specified.")
  endtry
  try
    r = this:give_quota(victim, @amount)
  except (E_INVARG)
    return player:tell(victim.name, " (", victim, ")  Is not an accountable object!")
  endtry
  if (r == amount)
    player:tell("Quota transfer successful.")
  elseif (r == {0, 0, 0})
    player:tell("Quota transfer failed.")
  else
    player:sub_tell("Quota transfer successful, but only %1 bytes, %2 objects, and %3 disk bytes were transferred.", r[1], r[2], r[3])
  endif
else
  player:tell("Syntax:  @give [n o*bjects][n b*ytes][n k*bytes][n dk*ilobytes][n db*ytes] to <player/project>")
  player:tell("         @take [n o*bjects][n b*ytes][n k*bytes][n dk*ilobytes][n db*ytes] to <player/project>")
endif
suspend(0)
dobjstr = tostr(victim)
this:("@quota")()
"Last modified by Dax (#789) on Thu Nov  8 11:53:52 2001 MST."
"This verb previously owned by manta (#7165), and chowned to $slacker upon dewizarding (Sat Aug 17 14:50:04 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:50:04 2002 MDT."
.