@verb #12:"@folder*1" none none none rdo #8084
@program #12:"@folder*1" none none none
if (player != this)
  return $msg:mtell("huh")
endif
if (this.audit_folders != {})
  for x in (this.audit_folders)
    player:tell("  [", x in this.audit_folders, "]: ", x[1], " (", length(x[2]), " objects in folders)")
  endfor
  player:tell("  [N]: Create a new folder")
  cmd = $cmd_utils:read("choose a folder to add or remove an object from")
  if ($su:is_numeric(cmd))
    try
      fname = this.audit_folders[idx = toint(cmd)][1]
    except (E_RANGE)
      return player:tell("You don't seem to have a folder numbered '", cmd, "'.")
    endtry
    player:tell({"  [A]: Add an object to folder", "  [D]: Remove an object from folder", "  [R]: Rename folder", "  [G]: Gather objects", "  [X]: Delete folder"})
    cmd = $cmd_utils:read("choose an action")
    force = tostr("@folder \"", fname, "\" ")
    if (cmd == "A" || cmd == "D")
      whatstr = $cmd_utils:read("object")
      if ($command_utils:object_match_failed(what = player:my_match_object(whatstr), whatstr))
        return
      endif
      force = tostr(force, cmd == "a" ? "+" | "-", what)
    elseif (cmd == "R")
      newname = $cmd_utils:read("new name")
      if (newname in $list_utils:slice(this.audit_folders, 1))
        return player:tell("You already have a folder named that.")
      endif
      force = tostr(force, "rename to \"", newname, "\"")
    elseif (cmd == "G")
      whatstr = $cmd_utils:read("the parent object to gather based upon")
      if ($command_utils:object_match_failed(what = player:my_match_object(whatstr), whatstr))
        return
      endif
      force = tostr(force, "++", tostr(what))
    elseif (cmd == "X")
      force = tostr(force, "delete")
    else
      return player:tell("I didn't understand that.")
    endif
    player:tell("Command: ", force)
    force_input(player, force)
    return
  elseif (cmd != "N")
    return player:tell("I don't understand that.")
  endif
endif
name = $cmd_utils:read("new folder name")
if (name in $list_utils:slice(this.audit_folders, 1))
  return player:tell("You already have a folder named that.")
endif
this.audit_folders = {@this.audit_folders, {name, {}}}
player:tell("Folder created.")
"Last modified by Dax (#789) on Tue May  3 14:09:29 2005 MDT."
.