@verb #12:"@check-quota" any none none rdo #55
@program #12:"@check-quota" any none none
"Run through all objects in the database and verify which objects a player really owns (obj.owner is always right, player.owned_objects sometimes lies).  Then verify the real disk sizes of all objects."
if (!valid(dobj = dobjstr ? dobj | this) && $command_utils:player_match_failed(dobj = player:match_entity(dobjstr), dobjstr))
  return
endif
whose = dobj == this ? "your" | dobj.name + "'s"
player:tell("Searching for ", whose, " objects...")
before = dobj.owned_objects
s = {}
for o in [#1..max_object()]
  if (valid(o) && o.owner == dobj)
    s = {@s, o}
  endif
  $command_utils:suspend_if_needed()
endfor
if (before != dobj.owned_objects)
  "Cute trick: @check-quota and @recreate low-numbered objects while it is running..."
  return player:tell("dobj.name +  appears to have created or recycled an object while ", verb, " was running.  ", verb, " exiting without making any changes.")
endif
dobj.owned_objects = s
player:tell(whose, " audit now contains: ", toliteral(s))
for x in (s)
  if (x:isa($garbage))
    player:sub_tell("Warning: %D owns the garbage object %1!", x)
  endif
  $cmd_utils:suspend_if_needed(1)
endfor
player:tell("Verifying the file size of all of ", whose, " objects...")
q = 0
for x in (dobj.owned_objects)
  q = q + x:_obj_disk_size(1)
  $cmd_utils:suspend_if_needed()
endfor
player:tell("All files verified. There is a total of ", $su:group_number(q), " bytes worth of files.")
"Last modified by Dax (#789) on Tue Jun  2 17:08:14 1998 EDT."
.