@verb #12:"@addfeature*! @add-feature*!" any none none rdo #55
@program #12:"@addfeature*! @add-feature*!" any none none
"Usage:  @addfeature <feature object(s)>"
"Add an object to your features list."
"@addfeature! adds the object at the top of your features list."
set_task_perms(player)
if (length(args) > 1)
  FOs = {}
  for x in (args)
    if (valid(dobj = this:my_match_object(x)))
      FOs = {@FOs, dobj}
    else
      $command_utils:object_match_failed(dobj, x)
    endif
  endfor
elseif (dobjstr)
  dobj = this:my_match_object(dobjstr)
  if ($command_utils:object_match_failed(dobj, dobjstr))
    return
  endif
  FOs = {dobj}
else
  return player:tell("Usage:  @addfeature &lt;object(s)&gt;")
endif
for x in (FOs)
  if (x in player.features)
    player:tell(x.name, " is already one of your features.")
  elseif (player:add_feature(x, verb[length(verb)] == "!"))
    player:tell($string_utils:nn(x), " added as a feature.")
  else
    player:tell("You can't seem to add ", $string_utils:nn(x), " to your features list.")
  endif
endfor
"Last modified by Dax (#789) on Thu Nov  8 11:38:30 2001 MST."
.