@verb #12:"^*" this none this rd #55
@program #12:"^*" this none this
"Syntax: ^ retypes the last command you entered."
"        ^<text> adds <text> to the last command and re-enters it."
"        ^<oldtext>^<newtext> retypes the last command, replacing <oldtext> with <newtext>."
if (player != this)
  return $msg:mtell("huh")
endif
tlc = ""
for x in ($list_utils:reverse(this.last_commands))
  if (`x[1] != "^" && x[1..5] != "@more" ! E_RANGE => 1')
    tlc = x
    break
  endif
endfor
set_task_perms(this)
try
  argstr = verb[2..$] + (argstr && " " + argstr)
except (E_RANGE)
  player:tell("> " + tlc)
  return force_input(this, tlc)
endtry
if (q = index(argstr, "^"))
  bit1 = argstr[1..q - 1]
else
  player:tell("> " + tlc + argstr[1..$])
  return force_input(this, tlc + argstr[1..$])
endif
if (!(r = index(argstr[q + 1..$], "^")))
  r = length(argstr) - 1
else
  r = r + q - 1
endif
bit2 = argstr[q + 1..r]
player:tell("> " + strsub(tlc, bit1, bit2))
force_input(this, strsub(tlc, bit1, bit2))
"Last modified by manta (#7165) on Sat Aug  1 12:26:40 1998 EDT."
"This verb previously owned by whiz (#3135), and chowned to $slacker upon dewizarding (Sat Aug 17 14:48:43 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:48:43 2002 MDT."
.