@verb #1177:"_kick" this none this rxdo #1177
@program #1177:"_kick" this none this
"Copied from Terra (#1000):_kick by Dax (#789) Aug 31 07:50:09 2002"
"Begin generic security check (_kick)"
if (verb == "_kick" && !args[1]:isa(this))
  raise(E_INVARG, "Illegal object", args[1])
  return E_INVARG
endif
"End generic security check (_kick)"
this:tell("[Starting DT kick.]")
"Remove junk from the db."
newdb = {}
for data in (this.intersection_db)
  if ($recycler:valid(data[2]) && data[2]:isa($intersection))
    newdb = {@newdb, data}
  endif
endfor
this.intersection_db = newdb
"Grow the intersections if it is too crowded."
r = 0
while create (this:is_crowded())
  for xy in ($list_utils:scramble(this:area(r)))
    $command_utils:suspend_if_needed()
    if (!this:xy_exists(@xy))
      "Found a non-existant intersection.  Create it."
      this:tell("[Creating new DT intersection for ", toliteral(xy), " ]")
      this:create(@xy)
      suspend(5)
      continue create
    endif
  endfor
  "No non-existant intersections at this radius.  Increment the radius."
  r = r + 1
endwhile
this:tell("[Finished DT kick.]")
"Last modified by DT_Mayor (#1177) on Sat Aug 31 10:58:01 2002 MDT."
.