@verb #110:"RFC822_message_headers" this none this rxdo #55
@program #110:"RFC822_message_headers" this none this
"Ack...another RFC Protocol.  As far as I know, the order is: Return-Path, Recieved, Date, Reply-To, From, Organization, Sender, To, Cc, Message-ID, Subject, Newsgroups, X-Mail-Agent"
{time, from, to, subject, ?replyto = ""} = args
from = `$tool:from_nn(from)[1] ! E_RANGE => from'
to = $tool:from_nn(to)
replyto = $tool:from_nn(replyto)
fromstr = tostr("From: " + $tool:email_address(from))
newsgroups = destr = {}
for dest in (to)
  if (dest:isa($newsgroup))
    newsgroups = {@newsgroups, dest}
    to = setremove(to, dest)
  else
    if (dest == to[1])
      destr = {"To: " + $tool:email_address(dest)}
    else
      destr = {@destr, "    " + $tool:email_address(dest)}
    endif
  endif
endfor
ngstr = {}
for x in (newsgroups)
  if (x == newsgroups[1])
    ngstr = {"Newsgroups: " + #119:newsgroup_name(x)}
  else
    ngstr = {@ngstr, "            " + #119:newsgroup_name(x)}
  endif
endfor
replystr = {}
for x in (replyto)
  if (x == replyto[1])
    replystr = {"Reply-To: " + $tool:email_address(x)}
  else
    replystr = {@replystr, "          " + $tool:email_address(x)}
  endif
endfor
datestr = tostr("Date: ", $time_utils:rfc1123_time(time))
orgstr = tostr("Organization: ", $name)
subjstr = tostr("Subject: ", subject)
"Forgive the multiple additions to 'headers', but I'm keeping it in this messy format so that headers can be added, removed, or moved around a little easier."
headers = {"Return-Path: " + fromstr[index(fromstr, "<")..$], "Recieved: by " + $site + "; " + $time_utils:rfc1123_time(time)}
headers = {@headers, datestr, @replystr, fromstr, orgstr, @destr}
headers = {@headers, "Message-ID: <" + $tool:message_id(time) + "@" + $site + ">"}
headers = {@headers, @ngstr}
headers = {@headers, subjstr}
headers = {@headers, "X-Mail-Agent:  " + $name}
return headers
"Last modified by Dax (#789) on Tue May 11 08:43:34 1999 MDT."
"This verb previously owned by Raptor (#6319), and chowned to $slacker upon dewizarding (Sat Aug 17 14:48:43 2002 MDT)."
"Last modified by Dax (#789) on Sat Aug 17 14:48:43 2002 MDT."
.