@verb #1108:"move" this none this rxdo #9342
@program #1108:"move" this none this
"This monster verb moves Morn around DS9, locks up the victim, deals with runaways, returns Morn to Quark's, and shouts the welcome."
caller == this || raise(E_PERM)
suspend(2)
path = {#1037, #994, #1916, #1548, #6431, #1039, #1036}
if (this.victim.location != this.location)
  dude:tell("Morn reports you to security.")
  #2359:set(this.victim, "", 3)
  this.victim = #-1
endif
while (valid(this.victim) || this.location != this.home)
  goal = path[this.active]
  if (goal == #1548)
    goal.key = 0
  endif
  if (valid(this.victim))
    this.victim:tell("Morn drags you from ", this.victim.location.name, " to ", goal.dest.name, ".")
    goal:move(this.victim)
  endif
  if (goal == #1548)
    if (valid(this.victim))
      #2359:set(this.victim, "Assaulted Morn", 3)
      #995:announce_all("Morn throws ", this.victim.name, " into the detention cell.")
      this.location:announce_all_but({this}, "Morn says, \"Lock cell.\"")
      this.victim = #-1
      suspend(3)
      this.location:announce_all_but({this}, "Morn says, \"Don't do that again!\"")
    endif
  else
    if (valid(this.victim))
      this.location:announce("Morn goes to ", goal.dest.name, ", still carrying ", this.victim.name, ".")
    else
      this.location:announce_all("Morn goes to ", goal.dest.name, ".")
    endif
    this.key = 0
    goal:move(this)
    this.key = #988
    if (valid(this.victim))
      this.location:announce("Morn has arrived.  He is carrying ", this.victim.name, " by the scruff of the neck.")
    endif
  endif
  suspend(2)
  if (valid(this.victim) && this.victim.location != this.location)
    this.victim:tell("Morn reports you to security.")
    #2359:set(this.victim, "Assaulted Morn", 3)
    this.victim = #-1
  endif
  this.active = this.active + 1
endwhile
audience = 0
suspend(1)
for dude in (this.location:contents())
  if (is_player(dude) && dude:connected())
    this.location:announce_all_but({dude, this}, dude:title() + " shouts, \"Morn!\"")
    dude:tell("You shout, \"Morn!\"")
    audience = 1
  endif
endfor
if (audience)
  this:notify("Everyone says, \"Morn!\"")
endif
suspend(4)
this.location:announce_all_but({this}, "Morn sits down at the bar and downs another drink.")
"Last modified by Dax (#789) on Mon May  7 14:37:14 2001 MDT."
.