@verb #1011:"@pastweek @never @pastday" none none none rxdo #7153
@program #1011:"@pastweek @never @pastday" none none none
"USAGE:  @never     list players who have never connected."
"        @pastweek  list of players who have connected in the past week."
"        @pastday   list of players who have connected in the past day."
this:update_usage(verb)
do_not_post_this = 1
"Use the @exempt verb to exempt players from these lists."
exempt = this.exempt
plyrs = {}
if (verb == "@never")
  for x in (players())
    if ($object_utils:has_property(x, "last_connect_time"))
      if (x.last_connect_time == $maxint && !(x in exempt))
        plyrs = setadd(plyrs, x)
      endif
    endif
  endfor
else
  if (verb == "@pastday")
    cutoff = time() - 24 * 60 * 60
  else
    cutoff = time() - 7 * 24 * 60 * 60
  endif
  for x in (players())
    if (x:has_property("last_connect_time"))
      if (x in connected_players() || x.last_connect_time > cutoff || x.last_disconnect_time > cutoff && x.last_connect_time != $maxint && !(x in exempt))
        plyrs = setadd(plyrs, x)
      endif
    endif
  endfor
endif
if (plyrs)
  player:tell("The following players have connected ", verb == "@never" ? "" | "in the ", verb[2..length(verb)], ".")
  $code_utils:show_who_listing(plyrs)
else
  player:tell("No players have connected ", verb == "@never" ? "" | "in the ", verb[2..length(verb)], ".")
endif
"Last modified Fri Jun 20 07:53:51 1997 EDT by Picard, #95@DarkMOO."
"Last modified by Absolute (#7153) on Fri Dec  8 16:47:27 2000 MST."
.