Subj : Strange...
To   : Matt Mc_Carthy
From : Jerry Schwartz
Date : Mon Feb 26 2001 11:57 pm

Hello, Matt...

   ----- msgedit.bat begins -----
rem     BAT file to invoke msged and Squish (if needed) - 09/26/95
echo off

rem     ****************************************************************
rem     Change History

rem     04/30/99        Switched to MsgedNT/TE
rem
rem                     - removed TAME
rem                     - cd to %binkdrive%:\msged
rem                     - changed paths to %binkley% where appropriate

rem     12/30/98        Removing TAME didn't accomplish anything, and Idle
rem                     Sensitivity doesn't seem to work with Msged, so I
rem                     put TAME back in

rem     10/31/98        The system clock is running slowly, and not in any
rem                     linear fashion.  On the off chance that the time lost
rem                     is proportional to the time spent in msged, I'm
rem                     removing TAME

rem     12/26/97        After installing a new version of Norton Utilities,
rem                     I noticed that msged is now taking all CPU time so
rem                     I put TAME back in

rem     10/14/95        Added environment variable for PKARC so it won't
rem                     leave junk files lying around

rem     09/26/95        Switched to Squish

rem     09/16/95        Installed version of msged/sq which calls DOS idle
rem                     interrupt, removed Tame; seems to work fine under
rem                     Windows 95

rem     3/19/91         Added msged.bsy semaphore file so that Squish won't
rem                     run while msged is running and step on the pointers
rem     ****************************************************************

rem     ==> IMPORTANT NOTE:
rem     If the binkdrive variable isn't set, we were run naked so assume it is
rem             the E: drive!

if "%binkdrive%"=="" set binkdrive=e
if "%binkley%=="" set binkley=%binkdrive%:\bink

set PKARCTMP=%binkdrive%:\SQUISH\ARCTEMP

rem     ****************************************************************

:CheckSemaphore

rem     Don't run msged if message base is busy

        if not exist %binkley%\msgbase.bsy goto Runmsged
                echo Message base is busy, waiting...
                pause
                goto CheckSemaphore
rem     *****************************************************************

:Runmsged

rem     Create the semaphore file
        echo msged running >%binkley%\msgbase.bsy
rem     ****************************************************************

rem     Run the editor

rem     e:\tame\tame.exe /i

        cd %binkdrive%:\msged
        %binkdrive%:\msged\msgednt.exe
rem     ****************************************************************

rem     Check to see if we entered any mail - any kind will do

if errorlevel 1 goto mademail
goto msgedexit

rem     ****************************************************************

:MadeMail

rem     If we created any mail, then we want to OUT and SQUASH it; Squish
rem     will handle any conflicts with Binkley activity

        cd %binkdrive%:\squish
        %binkdrive%:\squish\sq386 out squash -f%binkley%\sqtoss.log 
-c%binkdrive%:\squish\squish.cfg -Q
                if errorlevel 5 goto MaxMsgsHit
                if errorlevel 4 goto EchoMailNetOut
                if errorlevel 3 goto NetMailOnly
                if errorlevel 2 goto EchoMailOut
                if errorlevel 1 goto SQFatalError

rem     Everything but a fatal error leads us to further processing

:MaxMsgsHit
:EchomailNetOut
:NetMailOnly
:EchoMailOut
                goto EndofSQ

rem     ****************************************************************

rem     ErrorLevel 1
:SQError

        echo Squish Error: Unknown Cause (ErrorLevel 2)
        echo Squish Error: Unknown Cause (ErrorLevel 2) >>%binkley%\squish.log
        goto EndofSQ

rem     ****************************************************************

rem     This is the end of the Squish processing; we delete the TOSSLOG file 
for
rem             a fresh start next time

:EndofSQ

        if exist %binkley%\sqtoss.log del %binkley%\sqtoss.log

:msgedexit

rem     Delete any files left by PKARC
        if exist %pkarctmp%\*. del %pkarctmp%\*.


rem     Delete the semaphore file
        del %binkley%\msgbase.bsy

   ----- msgedit.bat ends -----

Regards,
Jerry
mailto:jerryschwartz@comfortable.com
http://www.writebynight.com

--- Msged/NT TE 05
 * Origin: Write by Night (1:142/928)

.